Sample Solutions for the XSLT Exercises of Lab 3
================================================

These are possible ways to express the XSLT transformations Lab 3. 
There are also many equivalent solutions.


------------------------------------------------------------------------------------
 1. Return a list, inside an element <recipes>, of recipes, containing
    for every recipe the recipe's title element and an element with
    the number of calories. Use different approaches:
    (a) express iteration by recursive calls of templates
    (b) express iteration by <xsl:for-each> elements.
    Create new elements 
    (a) by explicit construction, that is by writing the tags into the
        code,
    (b) by dynamic construction, that is, by using <xsl:element> and
        <xsl:attribute> elements,
    (c) by shallow and deep copying, wherever the latter is possible.



 Approaches: (a) Recursive calls and (a) explicit construction


<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0"
            encoding="iso-8859-1" indent="yes"/>

<xsl:template match="/">
  <xsl:apply-templates select="recipes"/>
</xsl:template>

<xsl:template match="recipes">
  <recipes>
    <xsl:apply-templates select="recipe"/>
  </recipes>
</xsl:template>

<xsl:template match="recipe">
  <recipe>
    <title>
      <xsl:value-of select="title"/>    
    </title>
    <calories>
      <xsl:value-of select="nutrition/@calories"/>    
    </calories>
  </recipe>
</xsl:template>

</xsl:stylesheet>


 Approaches: (a) Recursive calls and (b) dynamic construction


<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0"
            encoding="iso-8859-1" indent="yes"/>

<xsl:template match="/">
  <xsl:apply-templates select="recipes"/>
</xsl:template>

<xsl:template match="recipes">
  <xsl:element name="recipes">
    <xsl:apply-templates select="recipe"/>
  </xsl:element>
</xsl:template>

<xsl:template match="recipe">
  <xsl:element name="recipe">
    <xsl:element name="title">
      <xsl:value-of select="title"/>    
    </xsl:element>
    <xsl:element name="calories">
      <xsl:value-of select="nutrition/@calories"/>    
    </xsl:element>
  </xsl:element>
</xsl:template>

</xsl:stylesheet>


 Approaches: (b) Iteration with for-each and (c) copying


<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0"
            encoding="iso-8859-1" indent="yes"/>

<xsl:template match="/">
  <xsl:for-each select="recipes">
    <xsl:copy>
      <xsl:for-each select="recipe">
        <xsl:copy>
          <xsl:copy-of select="title"/>
          <xsl:element name="calories">
            <xsl:value-of select="nutrition/@calories"/>
          </xsl:element>
        </xsl:copy>
      </xsl:for-each>
    </xsl:copy>
  </xsl:for-each>
</xsl:template>

</xsl:stylesheet>


------------------------------------------------------------------------------------
 2. Using iteration by recursion, return a similar list, alphabetically
    ordered according to title,
   

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0"
            encoding="iso-8859-1" indent="yes"/>

<xsl:template match="/">
  <xsl:apply-templates select="recipes"/>
</xsl:template>

<xsl:template match="recipes">
  <recipes>
    <xsl:apply-templates select="recipe">
      <xsl:sort select="title"/>
    </xsl:apply-templates>
  </recipes>
</xsl:template>

<xsl:template match="recipe">
  <recipe>
    <title>
      <xsl:value-of select="title"/>    
    </title>
    <calories>
      <xsl:value-of select="nutrition/@calories"/>    
    </calories>
  </recipe>
</xsl:template>

</xsl:stylesheet>


------------------------------------------------------------------------------------
 3. Using Iteration by means of <xsl:for-each>, return a similar list, 
    ordered according to calories in descending order.

    (Hint: Consult the Web, e.g. the website www.w3schools.com, if you
     encounter difficulties with the ordering.)


<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0"
            encoding="iso-8859-1" indent="yes"/>

<xsl:template match="/">
  <xsl:for-each select="recipes">
    <xsl:copy>
      <xsl:for-each select="recipe">
        <xsl:sort select="nutrition/@calories" order="descending" data-type="number"/>
        <xsl:copy>
          <xsl:copy-of select="title"/>
          <xsl:element name="calories">
            <xsl:value-of select="nutrition/@calories"/>
          </xsl:element>
        </xsl:copy>
      </xsl:for-each>
    </xsl:copy>
  </xsl:for-each>
</xsl:template>

</xsl:stylesheet>


------------------------------------------------------------------------------------
 4. Return a similar list, with title as attribute and calories as
    element content.


<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0"
            encoding="iso-8859-1" indent="yes"/>

<xsl:template match="/">
  <xsl:for-each select="recipes">
    <xsl:copy>
      <xsl:for-each select="recipe">
        <xsl:sort select="nutrition/@calories" order="descending" data-type="number"/>
        <xsl:copy>
          <xsl:attribute name="title" select="title"/>
          <xsl:element name="calories">
            <xsl:value-of select="nutrition/@calories"/>
          </xsl:element>
        </xsl:copy>
      </xsl:for-each>
    </xsl:copy>
  </xsl:for-each>
</xsl:template>

</xsl:stylesheet>


-----------------------------------------------------------------------------
 5. Return a list, inside an element <recipes>, of recipes, where each
    recipe contains the title and the top level ingredients, while
    dropping the lower level ingredients.


<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0"
            encoding="iso-8859-1" indent="yes"/>

<xsl:template match="/">
  <xsl:apply-templates select="recipes"/>
</xsl:template>

<xsl:template match="recipes">
  <recipes>
    <xsl:apply-templates select="recipe"/>
  </recipes>
</xsl:template>

<xsl:template match="recipe">
  <recipe>
    <title>
      <xsl:value-of select="title"/>    
    </title>
    <xsl:apply-templates select="ingredient"/> 
  </recipe>
</xsl:template>

<xsl:template match="ingredient">
  <ingredient>
    <xsl:copy-of select="@*"/>    
  </ingredient>
</xsl:template>

</xsl:stylesheet>